Class parameters

Like formulas, classes can also have parameters and a title, which are declared in the default section. This matters only if the class is in turn declared as a class parameter for a formula. In this case, the class appears in the list of parameters in the Layer Properties tool window, with the parameters for the class grouped with the title of the class. (See Example 1 - Formula classes for a screen shot.)

Here is a simple example of a class that implements a simple bailout condition for a Mandelbrot-like fractal formula. The bailout value is exposed as a parameter.

class Bailout {
public:
  func Bailout()
    ; Empty constructor, see Extending class parameters
  endfunc
  bool func hasBailedOut(const complex z)
    return |z| > @bailout
  endfunc
default:
  title = "Simple Bailout"
  float param bailout
    caption = "Bailout value"
    default = 4
    min = 1
  endparam
}

To use this class and include its parameters in the parameter list for a formula, declare a class parameter in the formula. A class parameter is declared by a parameter block with the name of the class as its type.

MandelbrotTest {
init:
  z = (0, 0)
  Bailout bo = new @bailoutParam
loop:
  z = sqr(z) + #pixel
bailout:
  !bo.hasBailedOut(z)
default:
  Bailout param bailoutParam
    caption = "Bailout Test"
  endparam
}

Notes

Normally, you create an instance of a class with parameters using new and the class name. In this case, all parameters always remain at the default value. The class parameter bailoutParam in the MandelbrotTest formula represents a variant of the Bailout class that has different parameter values, set by the user. To create an object that uses these user-set parameter values, use the new operator with the class parameter as shown above.
You can create more than one object from a single class parameter, and you can have multiple class parameters of the same class type, which have their own independent set of parameters.
Inside a class, all parameters must be declared by a parameter block. (In contrast, formulas can have undeclared parameters for Fractint compatibility.)
Optionally, a class can also contain a rating setting in its default section.

Next: Extending class parameters